hide-and-seek/maps/mp/mods/disableClassMenu.gsc

#include common_scripts\utility;
#include maps\mp\_utility;
#include maps\mp\gametypes\_hud_util;

disableClassMenu()
{
	level.originalAllies = level.allies;
	level.originalAxis = level.axis;
	level.originalAutoAssign = level.autoAssign;
	level.allies = ::classMenu_menuAllies;
	level.axis = ::classMenu_menuAxis;
	level.autoAssign = ::classMenu_menuAutoAssign;

	game["menu_changeclass_axis"] = game["menu_team"];
	game["menu_changeclass_allies"] = game["menu_team"];
}


classMenu_autoClass()
{
	self closepopupMenu();
	self closeInGameMenu();
	self.selectedClass = true;
	self [[level.class]]("class1");
}


classMenu_menuAllies()
{
	self [[level.originalAllies]]();

	if (self.pers["team"] == "allies")
	{
		self classMenu_autoClass();
	}
}

classMenu_menuAxis()
{
	self [[level.originalAxis]]();

	if (self.pers["team"] == "axis")
	{
		self classMenu_autoClass();
	}
}

classMenu_menuAutoAssign()
{
	self [[level.originalAutoAssign]]();

	self classMenu_autoClass();
}