hide-and-seek/maps/mp/mods/disableClassMenu.gsc

#include common_scripts\utility;
#include maps\mp\_utility;
#include maps\mp\gametypes\_hud_util;

disableClassMenu()
{
	// https://github.com/promod/CoD4-Mod-Tools/blob/e88c6f106cb124547e514e658001fcdc4c4e15f3/raw/ui_mp/choices_setup_teams.menu#L57
	SetDvar("scr_oldschool", 1);

	// found in https://github.com/promod/CoD4-Mod-Tools/blob/e88c6f106cb124547e514e658001fcdc4c4e15f3/raw/ui_mp/scriptmenus/ingame.menu#L94
	// but it's probably no longer in use seeing as the whole file has been commented out.
	SetDvar("ui_allow_classchange", 0);

	level.originalAllies = level.allies;
	level.originalAxis = level.axis;
	level.originalAutoAssign = level.autoAssign;
	level.allies = ::classMenu_menuAllies;
	level.axis = ::classMenu_menuAxis;
	level.autoAssign = ::classMenu_menuAutoAssign;

}


classMenu_autoClass()
{
	self closepopupMenu();
	self closeInGameMenu();
	self.selectedClass = true;
	self [[level.class]]("class1");
}


classMenu_menuAllies()
{
	self [[level.originalAllies]]();

	if (self.pers["team"] == "allies")
	{
		self classMenu_autoClass();
	}
}

classMenu_menuAxis()
{
	self [[level.originalAxis]]();

	if (self.pers["team"] == "axis")
	{
		self classMenu_autoClass();
	}
}

classMenu_menuAutoAssign()
{
	self [[level.originalAutoAssign]]();

	self classMenu_autoClass();
}