#include common_scripts\utility;
#include maps\mp\_utility;
#include maps\mp\gametypes\_hud_util;

disableClassMenu()
{
	level.originalAllies = level.allies;
	level.originalAxis = level.axis;
	level.allies = ::menuAllies;
	level.axis = ::menuAxis;
	level.autoAssign = ::menuAutoAssign;

}


autoClass()
{
	self closepopupMenu();
	self closeInGameMenu();
	self.selectedClass = true;
	self [[level.class]]("class1");
}


menuAllies()
{
	self [[level.originalAllies]]();

	if (self.pers["team"] == "allies")
	{
		self autoClass();
	}
}

menuAxis()
{
	self [[level.originalAxis]]();

	if (self.pers["team"] == "axis")
	{
		self autoClass();
	}
}

menuAutoAssign()
{
	self closeMenus();

	assignment = getTeamAssignment();

	if (isDefined(self.pers["team"]) && (self.sessionstate == "playing" || self.sessionstate == "dead"))
	{
		if (assignment == self.pers["team"])
		{
			self beginClassChoice();
			return;
		}
		else
		{
			self.switching_teams = true;
			self.joining_team = assignment;
			self.leaving_team = self.pers["team"];
			self suicide();
		}
	}

	self addToTeam(assignment);
	self.pers["class"] = undefined;
	self.class = undefined;

	if (!isAlive(self))
		self.statusicon = "hud_status_dead";

	self notify("end_respawn");

	self autoClass();
}